RE: st: modifying egen to add a replace feature

[Pradipto Banerjee <pradipto.banerjee@adainvestments.com>]

Nick, I knew we could count on you :-) This is great. Works perfectly so far. Many thanks.


-----Original Message-----
From: owner-statalist@hsphsun2.harvard.edu [mailto:owner-statalist@hsphsun2.harvard.edu] On Behalf Of Nick Cox
Sent: Thursday, July 19, 2012 2:15 PM
To: statalist@hsphsun2.harvard.edu
Subject: Re: st: modifying egen to add a replace feature

I gave in and wrote a -ereplace- if only if to scotch any impression
that it's a big deal. Careful scrutiny will show that it is,
naturally, almost identical to -egen-. But (a) it's not much tested
(b) I am not taking this further.

Nick

program define ereplace, byable(onecall) sortpreserve
        version 6, missing

        local cvers = _caller()

        gettoken type 0 : 0, parse(" =(")
        gettoken name 0 : 0, parse(" =(")

        if `"`name'"'=="=" {
                local name `"`type'"'
                local type : set type
        }
        else {
                gettoken eqsign 0 : 0, parse(" =(")
                if `"`eqsign'"' != "=" {
                        error 198
                }
        }

        confirm variable `name'

        gettoken fcn 0 : 0, parse(" =(")
        gettoken args 0 : 0, parse(" ,") match(par)
        capture qui findfile _g`fcn'.ado
        if (`"`r(fn)'"' == "") {
                di as error "unknown egen function `fcn'()"
                exit 133
        }
        if `"`par'"' != "(" {
                exit 198
        }
        if `"`args'"' == "_all" {
                version 7.0, missing
                unab args : _all
                local args : subinstr local args "`_sortindex'"  "", all word
                version 6.0, missing
        }

        syntax [if] [in] [, *]
        if _by() {
                local byopt "by(`_byvars')"
                local cma ","
        }
        else if `"`options'"' != "" {
                local cma ","
        }
        tempvar dummy
        global EGEN_Varname `name'
        version 7.0, missing
        global EGEN_SVarname `_sortindex'
        version 6.0, missing
        if ("`fcn'" == "mode") {
                local vv : display "version " string(`cvers') ", missing:"
        }
        capture noisily `vv' _g`fcn' `type' `dummy' = (`args') `if' `in' /*
                */ `cma' `byopt' `options'
        global EGEN_SVarname
        global EGEN_Varname
        if _rc { exit _rc }
        quietly count if missing(`dummy')
        if r(N) {
                local s = cond(r(N)>1,"s","")
                di in bl "(" r(N) " missing value`s' generated)"
        }
        replace `name' = `dummy'
end

On Thu, Jul 19, 2012 at 3:12 PM, William Buchanan
<william@williambuchanan.net> wrote:
> You might try using -egen- to create a series of -tempvars- that you combine into a single variable after all the computations.  Either way, it would probably be helpful if you share the solution that works for you with the list since others have probably had similar issues.
>
> HTH,
> Billy
>
> Sent from my iPhone
>
> On Jul 19, 2012, at 6:36, Pradipto Banerjee <pradipto.banerjee@adainvestments.com> wrote:
>
>> That's exactly the issue I had. I had tried to use -replace- as an option, but Stata threw a error message saying that the variable is already defined.
>>
>> -----Original Message-----
>> From: owner-statalist@hsphsun2.harvard.edu [mailto:owner-statalist@hsphsun2.harvard.edu] On Behalf Of Nick Cox
>> Sent: Thursday, July 19, 2012 4:09 AM
>> To: statalist@hsphsun2.harvard.edu
>> Subject: Re: st: modifying egen to add a replace feature
>>
>> Not so. Writing a new -egen- function so that it takes a -replace-
>> option is not the issue here. -egen- will throw out the call if -y- is
>> an existing variable before the function code is even entered. The
>> issue is cloning -egen- to do the replacement.
>>
>> As I've signalled elsewhere, I think  it is easiest just to -drop-
>> what you don't want and/or do a -replace- afterwards.
>>
>> Nick
>>
>> On Thu, Jul 19, 2012 at 8:13 AM, Maarten Buis <maartenlbuis@gmail.com> wrote:
>>> On Wed, Jul 18, 2012 at 5:00 PM, Pradipto Banerjee wrote:
>>>> Is it possible to rewrite or modify egen, or create an ado file, such that I can simply write like this:
>>>>
>>>> bysort x: egen y = myfunc (y, a, b, ...), replace
>>>
>>> Yes, the logic behind the way -egen- works is that if you type -egen y
>>> = myfunc()-, -egen- will look for a file _gmyfunc.ado, which
>>> implements the function myfunc() and it also passes the option you
>>> have specified to that .ado file. So you can write your own -egen-
>>> functions. The easiest way to get started is to look at an existing
>>> similar function and addept that, e.g. look at -viewsource _gmean.ado.
>>>

*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/

 This communication is for informational purposes only. It is not intended to be, nor should it be construed or used as, financial, legal, tax or investment advice or an offer to sell, or a solicitation of any offer to buy, an interest in any fund advised by Ada Investment Management LP, the Investment advisor.  Any offer or solicitation of an investment in any of the Funds may be made only by delivery of such Funds confidential offering materials to authorized prospective investors.  An investment in any of the Funds is not suitable for all investors.  No representation is made that the Funds will or are likely to achieve their objectives, or that any investor will or is likely to achieve results comparable to those shown, or will make any profit at all or will be able to avoid incurring substantial losses.  Performance results are net of applicable fees, are unaudited and reflect reinvestment of income and profits.  Past performance is no guarantee of future results. All f!
 inancial data and other information are not warranted as to completeness or accuracy and are subject to change without notice.

Any comments or statements made herein do not necessarily reflect those of Ada Investment Management LP and its affiliates. This transmission may contain information that is confidential, legally privileged, and/or exempt from disclosure under applicable law. If you are not the intended recipient, you are hereby notified that any disclosure, copying, distribution, or use of the information contained herein (including any reliance thereon) is strictly prohibited. If you received this transmission in error, please immediately contact the sender and destroy the material in its entirety, whether in electronic or hard copy format.

*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/