Re: st: Obtaining rrr's of margins after mlogit

[Maarten Buis <maartenlbuis@gmail.com>]

On Thu, Mar 22, 2012 at 12:03 PM, John Francis wrote:
> Now, what do I do in order to check how much the effect has changed
> between cohorts, and whether or not said change is significant? How
> does the constant play into this? I think these things would be fairly
> obvious to see if I could use -margins, over()-, but as it is, the
> -mlogit- output is quite confusing to me...

I think what you are looking for what is discussed in

M.L. Buis (forthcoming) "Stata tip 106: With or without reference",
The Stata Journal, 12(1).
<http://www.maartenbuis.nl/publications/ref_cat.html>

With these tricks you can easily get separate relative risk ratios for
each category, which is sometimes easier to understand. To create an
example with -mlogit-:

*------------------------ begin example -------------------------
sysuse nlsw88, clear

gen occ_cat = cond(occupation < 3                 , 1,      ///
              cond(inlist(occupation, 5, 6, 8, 13), 2, 3))  ///
              if occupation < .
label define occ_cat 1 "high"   ///
                     2 "middle" ///
                     3 "lower"
label value occ_cat occ_cat
			
gen marst = never_married + 2*married
label define marst 1 "divorced/widowed" ///
                   2 "never married"    ///
                   3 "married"
label value marst marst

gen c_grade = grade - 12			
			
mlogit occ_cat ibn.marst ibn.marst#c.c_grade, rrr nocons
*------------------------- end example --------------------------
(For more on examples I sent to the Statalist see:
http://www.maartenbuis.nl/example_faq )

So the relative risks comparing high with lower occupations (in the
panel labeled "high") for divorced/widowed is .54 person with a higher
job for every person with a lower job. Similarly, for never married it
is .38 person with a higher job for every person with a lower job and
for married it is .43 persons with a higher job for every person with
a lower job. All these relative risks (I like to call them odds [*])
refer to persons with high school (12 years of education).

A year increase in education is associated with an increase in the
relative risks by a factor 1.23, 1.44, and 1.29 for divorced/widowed,
never married, and married persons respectively.

Hope this helps,
Maarten

[*] <http://www.stata.com/statalist/archive/2007-02/msg00085.html>

--------------------------
Maarten L. Buis
Institut fuer Soziologie
Universitaet Tuebingen
Wilhelmstrasse 36
72074 Tuebingen
Germany


http://www.maartenbuis.nl
--------------------------
*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/