Re: st: question about seqlogit

[Alberto R Osella <arosella@irccsdebellis.it>]

Stupid question. Forgot it

Alberto R. Osella, MD, PhD
Laboratorio di Epidemiologia e Biostatistica
IRCCS Saverio de Bellis
Via Turi, 27
70013 Castellana Grotte (BA)
Italia
Tel:    +39 0804994655
Fax:    +39 0804994650
e-mail: arosella@irccsdebellis.it


Il 29/11/2011 13:30, Maarten Buis ha scritto:
> On Tue, Nov 29, 2011 at 12:56 PM, Alberto R Osella wrote:
> > It may be this is not the right place to formulate this question but I don't
> > know other way.
> > I'm using Stata 12 on win7 and I've performed an sequental logit by using
> > the user-written -seqlogit-
> > which works fine. After taking a look at the references on -help seqlogit-
> > I've read two references by Buis M.
> > In one of them there is a graphic that I was not to able to reproduce
> > (http://www.maartenbuis.nl/dissertation/chap_6.pdf, pag 124, Figure 6.8:
> > Contribution of each transition to IEOut).
> > Is there someone who has used this command and have do this graphic?
> Alberta has asked me privately before, which in this case is correct
> as it involves one of my programs and my dissertation. I was busy at
> the time and I forgot. Sorry about that.
>
> Below is an example:
>
> *---------------- begin example -------------------
> use http://fmwww.bc.edu/repec/bocode/g/gss.dta, clear
> seqlogit degree sibs south country suburb city ///
>           coh if black == 0, or                 ///
>           tree(0:1 2 3 4, 1:2 3 4, 2 : 3 4 , 3 : 4)     ///
>           ofinterest(paeduc) over(coh)          ///
>           levels(0=9, 1=12, 2=14, 3=16, 4=18)
>
> preserve
>
> keep if e(sample)
> 		
> replace sibs = 1
> replace south = 0 // i.e. north
> replace country = 0
> replace suburb = 0
> replace city = 0 // i.e. town
>
> sum paeduc, meanonly
> replace paeduc = r(mean)
> replace _paeduc_X_coh = paeduc*coh
>
> bys coh : keep if _n == 1
> 		
> predict w* , trweight
> forvalues i = 1/4 {
> 	gen contr`i' = w`i'*([#`i']_b[paeduc]+ [#`i']_b[ _paeduc_X_coh]*coh)
> }		
>
> gen contr0 = 0
> replace contr2 = contr1 + contr2
> replace contr3 = contr2 + contr3
> replace contr4 = contr3 + contr4
>
> twoway rarea contr0 contr1 coh || ///
>         rarea contr1 contr2 coh || ///
>         rarea contr2 contr3 coh || ///
>         rarea contr3 contr4 coh ,  ///
>         xlab(2(2)8)                ///
>         legend(order( 1 "attain high school" ///
>                       2 "any college versus high school" ///
>                       3 "junior college versus more"    ///
>                       4 "bachelor versus graduate" ) pos(6))
>
> restore
> *---------------- end example -------------------
>
> Hope this helps,
> Maarten
>
> --------------------------
> Maarten L. Buis
> Institut fuer Soziologie
> Universitaet Tuebingen
> Wilhelmstrasse 36
> 72074 Tuebingen
> Germany
>
>
> http://www.maartenbuis.nl
> --------------------------
> *
> *   For searches and help try:
> *   http://www.stata.com/help.cgi?search
> *   http://www.stata.com/support/statalist/faq
> *   http://www.ats.ucla.edu/stat/stata/
*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/