st: Re: Two part model vs Tobit vs Heckman

[Maarten Buis <maartenlbuis@gmail.com>]

--- Andrew Tan Khee Guan wrote me privately:
> In a paper I'm writing on physical activity, I used the Heckman to model
> participation likelihood and duration on physical activity. However, the
> journal reviewer wants me to consider the Tobit model as well as the
> Two-Part model (Probit/OLS).
<snip>
> However, when comparing the Two-Part model, am I right to use the following
> Stata command?
>
> probit dep $indep
> mfx
> reg dep $indep if dep>0
>
> Is that all? But how would I be able to compare across models? While the
> marginal effect of the probability of the Two-Part model is comparable to
> both Heckman and Tobit, how would the single OLS equation compare to the
> conditional and unconditionals of the former?
>
> Is there a test to choose between the three estimators?

Such questions must be sent to the statalist rather than individual
members. The reasons for that are explained here:
<http://www.stata.com/support/faqs/res/statalist.html#private>

The two part model is a Heckman model that assumes that there is no
correlation between the error terms of the selection equation and the
"wage/activity" equation. You can estimate this simply by estimating
separate probit and linear regression models (as you already did), or
you can use -heckman- and impose the constraint that the correlation
between error terms is 0. I wrote a Stata tip on imposing these types
of constraints in Stata (M.L. Buis, forthcomming). Using -heckman-
with the constraint has the advantage that you can use exactly the
same post-estimation commands as you already used for your regular
Heckman model.

The test that compares the Heckman model with the two part model is
reported at the bottom of the output of -heckman- for your regular
Heckman model (the line that starts with "LR test of indep. eqns. (rho
= 0):").

In the example below you can see that estimating the two models
separately or constraining the correlation to be 0 results in the same
parameters:

*-------------- begin example ---------------
webuse womenwk, clear

gen byte sel = missing(wage)

// two part model using -reg- and -probit-
reg wage educ age
probit sel married children educ age

// two part model using -heckman-
constraint 1 [athrho]_b[_cons] = 0
heckman wage educ age,                    ///
        select(married children educ age) ///
        constraint(1)
*--------------- end example ----------------
(For more on examples I sent to the Statalist see:
http://www.maartenbuis.nl/example_faq )

Hope this helps,
Maarten

M.L. Buis (forthcomming) "Stata tip 97: Getting at rhos and sigmas",
The Stata Journal, 11(2).
<http://www.maartenbuis.nl/publications/sigma_rho.html>

--------------------------
Maarten L. Buis
Institut fuer Soziologie
Universitaet Tuebingen
Wilhelmstrasse 36
72074 Tuebingen
Germany


http://www.maartenbuis.nl
--------------------------
*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/