Re: st: Suest v/s biprob in stata 11

[Maarten buis <maartenbuis@yahoo.co.uk>]

--- On Sun, 4/7/10, Prakash Kashwan wrote:
> I have a couple of queries regarding how suest works in
> Stata 11. The new user friendly menus use biprob command,
> which gives me different results compared to when I use
> suest posestimation command - I wonder if biprob does
> utilize the leverage offered by correlating residuals
> of two models involved. 

Yes, you can see in the example below that when you 
constrain that correlation to 0, both -biprobit- and
-suest- give the same estimates. 

*----------------------- begin example ------------------
webuse school
biprobit (private = logptax loginc years)     ///
         (vote = logptax years)
est store biprobit

probit private logptax loginc years
est store a

probit vote logptax years

est store b
suest a b
est store suest

constraint 1 [athrho]_cons=0
biprobit (private = logptax loginc years)      ///
         (vote = logptax years), constraint(1)
est store biprobit_constrained

est table biprobit suest biprobit_constrained, ///
    equations(1, 2)
*-------------------- end example -----------------
(For more on examples I sent to the Statalist see: 
http://www.maartenbuis.nl/example_faq )

Note that -biprobit-, and many other Stata commands,
maximizes the likelihood with respect to the Fisher's
z transformation (or the inverse hyperbolic tangent
of the correlation). This transformed correlation 
is stored in the parameter _cons in the equation 
athrho. The correlation is 0 when this transformed 
correlation is 0, so the appropriate constraint is
-constraint 1 [athrho]_cons=0-.

Hope this helps,
Maarten

--------------------------
Maarten L. Buis
Institut fuer Soziologie
Universitaet Tuebingen
Wilhelmstrasse 36
72074 Tuebingen
Germany

http://www.maartenbuis.nl
--------------------------


      

*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/