Probably you just want one omnibus measure of balance (an F stat) but try out:
u http://pped.org/lalonde.dta, clear
g age2=age^2
g ed2=educ^2
qui psmatch2 t age age2 educ ed2 re74
pstest age age2 educ ed2 re74
* test joint equality of all means
preserve
keep if _w<.
expand _w
qui reg t age age2 educ ed2 re74
di e(F)
qui hotelling age age2 educ ed2 re74, by(t)
di (r(N)-r(k)-1)/(r(N)-2)/r(k)*r(T2)
* or test vars one by one
foreach v in age age2 educ ed2 re74 {
qui ttest `v', by(t)
di "`v' p-value:" r(p)
}
restore
* or test one by one with paired data
sort _id
foreach v in age age2 educ ed2 re74 {
qui g C`v'=`v'[_n1]
qui ttest `v'=C`v'
di "`v' p-value:" r(p)
}
On Wed, Nov 25, 2009 at 2:50 PM, Martin Weiss <[email protected]> wrote:
>
> <>
>
> It is easy to -display- the call to the estimation command that -eststo-
> picks up and -esttab- displays. Taking the example at
> http://cameron.econ.ucdavis.edu/mmabook/mmaprograms.html:
>
>
> *******
> u http://cameron.econ.ucdavis.edu/mmabook/nswpsid.dta, clear
>
> psmatch2 TREAT AGE AGESQ EDUC EDUCSQ
>
> eststo psttest: pstest AGE AGESQ EDUC EDUCSQ, /*
> */ sum t(TREAT)
> esttab psttest
>
> di in r "`e(cmdline)'"
> *******
>
> The only difficulty here is the temporary variable that they condition on...
>
>
> The return list from -pstest- contains only -scalar-s, so you would have to
> -trace- the command to see how you can replicate the calculation of your
> desired results...
>
>
> HTH
> Martin
>
>
> -----Original Message-----
> From: [email protected]
> [mailto:[email protected]] On Behalf Of Peer Skov
> Sent: Mittwoch, 25. November 2009 19:12
> To: [email protected]
> Subject: st: Retrieving statistics after pstest to use with estout
>
> Dear listers,
> After running a psmatch2 estimation I use pstest to assess the balancing. I
> would like to set-up an .rtf table showing these t-statistics and the
> achieved percentage bias reduction for each variable. To avoid copy-typing I
> usually use estout/esttab, however, I haven't been able to reproduce an .rtf
> table holding my desired statistics.
>
> So far I have tried the following:
> eststo psttest: pstest [varlist], sum t(d)
> esttab pstest
> That gave me the coeff. and t-stats from (what I think is) a probit on
> treatment status on the matched sample.
>
> Additionally I have tried using [return] after pstest, my idea was to
> combine it with estadd. But as far as I can tell [return] did not have
> variable specific statistics.
>
> As the paper is still in version 1 and we balance on 46 variables and
> examine outcomes for 3 different treatments stata generated tables is
> considerable time-saving as well as error minimizing. Therefore, I will be
> thankful for all suggestions!
>
> Best,
> Peer.
*
* For searches and help try:
* http://www.stata.com/help.cgi?search
* http://www.stata.com/support/statalist/faq
* http://www.ats.ucla.edu/stat/stata/
