Herve STOLOWY:
I would use -suest- for your problem. -sureg- gives you more or less
the same answer as two separate OLS regressions when both regressions
have the same RHS variables, but it does allow you to test across
equations. If that is all you want, and you think the OLS assumptions
are justified, it may be preferable, I suppose. -suest- gives you the
same point estimates as the separate regressions, even when RHS
variables differ across equations, but will give you slightly
different variance estimates--it also estimates additional covariance
terms--and it has more flexibility (there is no vce or cluster option
on -sureg- for example). Try e.g.
sysuse auto, clear
qui sureg (mpg weight=foreign length), dfk
mat sureg=e(V)
est sto sureg
qui reg mpg foreign length
est sto r1
qui reg weight foreign length
est sto r2
qui suest r1 r2
mat suest=e(V)
est sto suest
esttab sureg r1 r2, unstack
esttab sureg suest, eq(1:1, 2:3)
mat li sureg
mat li suest
On Mon, Apr 27, 2009 at 10:29 AM, Martin Weiss <[email protected]> wrote:
> Maybe this post http://www.stata.com/statalist/archive/2007-08/msg00238.html
> and answers help answer your question...
> -----Ursprüngliche Nachricht-----
> Von: [email protected]
> [mailto:[email protected]] Im Auftrag von Herve STOLOWY
> Gesendet: Montag, 27. April 2009 16:15
> An: [email protected]
> Betreff: st: Difference between -suest- and -sureg-
>
> Dear Statalisters:
>
> A few days ago, I asked a question about how to test the difference in the
> growth rate of two variables. I received several interesting answers and
> Austin Nichols suggested the use of -suest-. If I adapt his suggestion to my
> problem, I have the following command lines:
>
> reg foreign_base time if time > 3 & time < 7
> est sto i
> reg foreign_match time if time > 3 & time < 7
> est sto v
> suest i v, cluster(company)
> test [i_mean]time=[v_mean]time
>
> Reading more on -suest- and -test-, I discovered the command -sureg-. I
> tried to adapt it to my problem:
>
> sureg (foreign_base time) (foreign_match time ) if time > 3 & time < 7
> test [foreign_base]time = [foreign_match]time
>
> It seems to me that the two procedures are very similar, although the
> results of the chi2 are not exactly the same (but they are consistent).
>
> Could someone explain to me the difference between the two procedures with
> regard to my problem? Is one "better" than the other (please forgive me in
> advance if my question is heretical). If the explanation is too long, could
> I find a useful reference?
>
> Best regards
>
> Herve Stolowy
>
*
* For searches and help try:
* http://www.stata.com/help.cgi?search
* http://www.stata.com/support/statalist/faq
* http://www.ats.ucla.edu/stat/stata/
