Ken <[email protected]>:
You probably want an [aweight] but with het-robust SEs it will look
just like a [pweight]. Note that -xtreg- will not allow weights that
vary over time within panel, but -areg- will. With a panel model with
at least 50 industries, or at least 20 balanced clusters, you would
want to cluster at the industry level to allow for arbitrary serial
correlation, and the df correction under clustering is slightly
different for -areg- and -xtreg- (but should make no real difference).
In this example there are only 10 clusters, so the SEs are probably
biased downward:
webuse grunfeld, clear
g w=round(1000*uniform())
xtreg inv mval [aw=w], fe
qui tab t, g(dt)
drop dt10
areg inv mval dt* [aw=w], a(com) r
est sto fe1
areg inv mval dt* [pw=w], a(com)
est sto fe2
areg inv mval dt* [pw=w], a(com) cl(com)
est sto fe3
esttab *, nogaps drop(dt*)
On Fri, Jun 27, 2008 at 6:06 PM, stata user <[email protected]> wrote:
> Hello All:
>
> I have a question on what would be the appropriate weights to use in a
> panel model I am running.
>
> I want to run a simple panel model of Y_{i, t} = a_it + X_{i, t} +
> industry-fixed effect + time-fixed effect. where i is the index
> industry and t is the index time. Now since some industres are more
> important than other industries (say industry A has more dollar sales
> than other industries), I want the regression to reflect this
> difference. That is, the relationship btw Y and X for industries with
> larger dollar sales shall carry a larger weight.
>
> I checked the stata menu and it looks that there are frequency weight,
> analytical weight, and importance weight. I do not think freq weight
> is appropriate here. Can anyone advise what is the appropriate weight
> to use in this setting? And how to implement it in stata?
>
> Many thanks.
>
> Ken
*
* For searches and help try:
* http://www.stata.com/support/faqs/res/findit.html
* http://www.stata.com/support/statalist/faq
* http://www.ats.ucla.edu/stat/stata/
