st: Re: F-test on fixed effects

[Kit Baum <baum@bc.edu>]

webuse grunfeld,clear
areg invest mvalue, a(company)  robust
scalar rss1 = e(rss)
scalar dfr = e(df_r)
scalar dfa = e(df_a)
regress invest mvalue, robust
scalar rss2 = e(rss)
scalar fstat = ((rss2-rss1)/dfa)/(rss1/dfr)
di "Resid SS with dummies " rss1
di "Resid SS without dummies " rss2
di "F statistic with " dfa " and " dfr " d.f. = " fstat

You can run this model with xtreg, fe and verify that it is calculating 
the same F-stat. Since the formula for this F depends only on residual 
sums of squares, and they are not modified by the use of robust 
s.e.'s...

You should also be able to use weights in both the models above.

Kit Baum, Boston College Economics
http://ideas.repec.org/e/pba1.html

On May 11, 2005, at 2:33 AM, France wrote:


> I need to conduct an F-test to test whether the fixed effects are
> jointly significant after the areg command (I use areg rather than
> xtreg because I use weights and adjust the standard errors using the
> robust option).
>
> I cannot figure out how to conduct that F-test because I do not know
> how to access the fixed effects estimates, Can anyone help me?
*
*   For searches and help try:
*   http://www.stata.com/support/faqs/res/findit.html
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/