Re: st: Formally comparing Tobit and Probit estimates

[Maarten Buis <maartenlbuis@gmail.com>]

---  On 21 January 2014 17:11, Radha Shah wrote:
>> I am using Stata version 12 for Windows. My question concerns
>> formally comparing the coefficients on a Probit and Tobit model.
>>
>> For the Tobit model I run the following,
>>
>> tobit y_tobit x1_tobit x2_tobit x3_tobit, ll(0)
>>
>> where y is either 0 or a positive value.
>>
>> For the probit model I run the following,
>>
>> probit y_probit x1_probit x2_probit x3_probit
>>
>> where y_probit is 0 if y_tobit == 0 and is equal to 1 if y_tobit>0.
>>
>> Can anyone help me with the coding in Stata to conduct a
>> statisitical test to test the hypothesis (for example): x1_tobit =
>> x1_probit.
>>
>> I have seen that I can informally compare the estimates by l
>> ooking for sign changes between them or visible differences in
>> magnitude between (_b[x1_tobit]/_b[sigma]) and (_b[x1_probit])
>> but I was looking for something more statistically formal.

-- On Tue, Jan 21, 2014 at 6:34 PM, Nick Cox answered:
> I am assuming that despite your notation the x_1*  etc. are really the
> same variable(s).
>
> I can't see that the idea of a formal test makes any sense.
>
> 1. The coefficients are not even in the same dimensions or units of
> measurement.
> (It's a pity that statistics courses and texts almost uniformly
> neglect such matters.)
>
> 2. The -tobit- model is linear; the -probit- model is nonlinear.

In general, Nick is correct, but as a special case what Radha is
looking for can make sense. A Tobit model is linear in the latent
dependent variable, but it also implies a probit model on the
probability of not being censored. Since in a Tobit model we also have
some non-censored observations we can identify the scale of that
latent variable, something we cannot do in a probit model. Concretely,
this means that we can estimate the error variance (sigma) in a Tobit
model, while in a probit model we fix it arbitrarily at 1. So, Radha's
idea of comparing (_b[x1]/_b[sigma]) with (_b[x1]) does make sense.

Radha could use -suest- to perform such a test. Below is an example:

*------------------ begin example ------------------
sysuse auto, clear
generate wgt=weight/1000
tobit mpg wgt, ll(17)
est store tobit

gen byte y = mpg > 17 if mpg < .
probit y wgt
est store probit

suest tobit probit
testnl ( [tobit_model]_b[wgt]   / [tobit_sigma]_b[_cons] =
[probit_y]_b[wgt]   ) ///
       ( [tobit_model]_b[_cons] / [tobit_sigma]_b[_cons] = [probit_y]_b[_cons] )
*------------------- end example -------------------
* (For more on examples I sent to the Statalist see:
* http://www.maartenbuis.nl/example_faq )

Hope this helps,
Maarten

---------------------------------
Maarten L. Buis
WZB
Reichpietschufer 50
10785 Berlin
Germany

http://www.maartenbuis.nl
---------------------------------
*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/faqs/resources/statalist-faq/
*   http://www.ats.ucla.edu/stat/stata/