Re: st: Calculating elasticities with an endogenous covariate in a translog production function

[Austin Nichols <austinnichols@gmail.com>]

Norman M <normanmva@gmail.com> :

Neither you nor Jason Russ <jasondruss@gmail.com> makes very clear
what quantity you want to estimate--is this a regression with log
output (lny) as the outcome?  In that case, the elasticity is not
dy/dx but perhaps you want the semielasticity dlny/dx instead?

If you want to increase the chance that someone responds, why not
follow the explicit guidance in the FAQ and show the command typed in
Stata?

You might consider simply demeaning all your covariates to make the
coef on X1 equal to its marginal effect, e.g.

set seed 1
drawnorm X2 Z e, n(1000) clear
g X1=e/4+Z
g y=exp(X2+X1+X1^2/5+X1*X2/100+e)
g X1X1=X1^2
g X1X2=X1*X2
g ZX2=Z*X2
g ZX1=Z*X1
g lny=ln(y)
reg lny c.X1##c.X1 c.X2##c.X2
margins, dydx(X1)
foreach v in X1 X2 {
 su `v', mean
 g double c`v'=`v'-r(mean)
 }
reg lny c.cX1##c.cX1 c.cX2##c.cX2
margins, dydx(cX1)
g cX1X1=cX1^2
g cX1X2=cX1*cX2
g ZcX2=Z*cX2
g ZcX1=Z*cX1
cap ssc inst ivreg2
ivreg2 lny cX2 (cX1 cX1X1 cX1X2=Z ZcX1 ZcX2)

but consider a -gmm- version for reasons given at
http://www.stata.com/meeting/snasug08/nichols_gmm.pdf

Why would you want the atmeans option on -margins-?


On Fri, Nov 29, 2013 at 5:42 PM, Norman M <normanmva@gmail.com> wrote:
> Hi everyone,
>
> I'm having the same problem that Jason posted, and I did not find a
> solution in the statalist. I was wondering if someone has a solution.

refers to:
http://www.stata.com/statalist/archive/2013-10/msg00034.html
*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/faqs/resources/statalist-faq/
*   http://www.ats.ucla.edu/stat/stata/