AW: st: -foreach- loop to fit regression at each level of a variable

["Klaus Pforr" <kpforr@googlemail.com>]

Dear Milena,

I guess that Sergiy hit bull's eye, but I would like to suggest instead of
having to wade through lengthy output after this loop solution, to estimate
your problem with sample-interactions.
If you use Serghiy's data:

set seed 123
clear
set obs 740
generate sample_level=floor(runiform()*4)
generate outcome=runiform()*4200>2000
generate var1=runiform()
generate var2=runiform()
generate var3=runiform()
generate id=floor(runiform()*2)

you can estimate the sample-specific effects with one command:

logistic outcome var1##sample_level  var2##sample_level var3##sample_level,
vce(cluster id)

best

Klaus

-----Ursprüngliche Nachricht-----
Von: owner-statalist@hsphsun2.harvard.edu
[mailto:owner-statalist@hsphsun2.harvard.edu] Im Auftrag von Sergiy Radyakin
Gesendet: Dienstag, 19. November 2013 17:12
An: statalist@hsphsun2.harvard.edu
Betreff: Re: st: -foreach- loop to fit regression at each level of a
variable

Milena, is this something you are after?

set seed 123
clear
set obs 740
generate sample_level=floor(runiform()*4)
generate outcome=runiform()*4200>2000
generate var1=runiform()
generate var2=runiform()
generate var3=runiform()
generate id=floor(runiform()*2)

levelsof sample_level, local(levs)

foreach n in `levs' {
  display ""
  display "======== Regression for level: `n'
===================================="
  logistic outcome var1 var2 var3 if sample_level==`n', vce(cluster id)
}

Best, Sergiy

On Tue, Nov 19, 2013 at 7:34 AM, Milena Przheska
<milena.przheska@cosmicdevelopment.com> wrote:
> Dear Statalist members,
>
> I am trying to fit the same logistic regression model using different
> samples from a data set and I am wondering if it is even possible to
> use a -foreach- loop to estimate regression models for each sample
> (indicated by a variable).
>
> I use the variable 'sample' to indicate the sample, but instead of
> writing the command over and over for each sample, I tried to do this
> with a -foreach- loop, something  like this:
>
> egen local sample_level = levelsof(sample)
>
> foreach n of sample_level {
> logistic outcome var1 var2 var3 if sample_level==`n', vce(cluster id)
> }
>
> As always, I would appreciate your help.
>
> Thanks,
> Milena
> *
> *   For searches and help try:
> *   http://www.stata.com/help.cgi?search
> *   http://www.stata.com/support/faqs/resources/statalist-faq/
> *   http://www.ats.ucla.edu/stat/stata/
*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/faqs/resources/statalist-faq/
*   http://www.ats.ucla.edu/stat/stata/


*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/faqs/resources/statalist-faq/
*   http://www.ats.ucla.edu/stat/stata/