Re: st: Time-dependent variables and the simon & makuch method

[Steve Samuels <sjsamuels@gmail.com>]

I've now had a chance to read the Simon and Makuch (1984) reference to a
survival plot for use with a time-varying binary covariate that can
change only once & in one direction. Their plot turns out to be
identical to the "landmark" method published the year before by Anderson
et al. (1983): one chooses a time point t*, and estimates survival
curves that start at that point.

The original stratum specific curves I showed are equivalent to setting
the landmark at t* = 0. This is unrealistic if everyone starts out with
the same value of the binary covariate. (That's not a problem for the
Stanford heart transplant data, where 34 people were transplanted the
day they enrolled.)

The modification below shows how to to do the Anderson-Simon-Makuch
curve for any landmark. I chose t* = 18 days, the median time to
transplant in the Stanford data.

***********CODE BEGINS*****************
webuse stan3, clear
stset t1, fail(died) id(id)

gen dummy=1
local lm = 18  /* landmark */
stcox  dummy, strata(posttran), if _t>=`lm'

predict surv, basesurv
separate surv, by(posttran)
tempvar t`lm'
gen `t`lm'' = _t-`lm'
twoway connect surv0 surv1 `t`lm'' if _t>=`lm', ///
sort  lp(dash solid) ///
saving(g`"`lm'"', replace) ///
title("Landmark = `lm' Days")
*********CODE ENDS*************


Obviously a -foreach- block could do the plots for several landmarks.



References:

Anderson, James R, Kevin C Cain, and Richard D Gelber. 1983. Analysis of
survival by tumor response. Journal of Clinical Oncology 1, no. 11:
710-719, downloaded from:
http://jco.publicaciones.saludcastillayleon.es/content/1/11/710.full.pdf

Simon, Richard, and Robert W Makuch. 1984. A non‐parametric graphical
representation of the relationship between survival and the occurrence
of an event: Application to responder versus non‐responder bias.
Statistics in Medicine 3, no. 1: 35-44.


Steve
sjsamuels@gmail.com


On 11 October 2013 21:59, Steve Samuels wrote:



Below I give the Mantel-Byar and Simon-Makuch references, with a
pertinent review by Anderson et al. (1983).

To answer your questions:

• When data with time-varying covariates are properly -stset- as
multiple-record data with the id() option, the log rank test in Stata
*is* the Mantel-Byar test.

• Replacement for KM plot

In a reply to Nichole Boyle
(http://www.stata.com/statalist/archive/2013-09/msg00408.html), I
suggested a "future" conditional incidence function" for a binary
time-dependent variable, and said I didn't know a reference. I do now.
Anderson and colleagues published a version in 1983 and called it
the "landmark method". They also criticized the use of the log rank test
and advocated the use of the Mantel-Byar test.

I don't have the Simon and Makuch reference, but here's a plot that
gives a reasonable result in the Stanford heart transplant data (webuse
stan3). It utilizes time-varying strata in the Cox model. The curve is
akin to a synthetic life table in demography (e.g. Arias, 2010), in which
current age-specific death rates are used to construct a life table. In
this case, waiting time to transplant plays the role of age. The table
has predictive value only if patients transplanted at _t and those
transplanted earlier have similar risks of death for subsequent times.
I'd expect dissimilar short term future risks, if only because of postoperative
mortality.


***********CODE BEGINS*****************
webuse stan3, clear
stset t1, fail(died) id(id)
sts test posttran, logrank  // Mantel-Byar
stcox posttran  // p-values should be close to above

/* -stcox- to get stratum-specific KM curves */
gen dummy=1
stcox dummy, strata(posttran)
predict surv, basesurv
separate surv, by(posttran)

twoway connect surv0 surv1 _t, sort  lp(dash solid)
*********CODE ENDS*************


References:

Anderson, James R, Kevin C Cain, and Richard D Gelber. 1983. Analysis of
survival by tumor response. Journal of Clinical Oncology 1, no. 11:
710-719, downloaded from:
http://jco.publicaciones.saludcastillayleon.es/content/1/11/710.full.pdf

Arias, E. 2010. United States life tables, 2006. Natl Vital Stat Rep 58,
no. 21: 1-40 www.cdc.gov/nchs/data/nvsr/nvsr58/nvsr58_21.pdf‎

Mantel, Nathan, and David P. Byar. 1974. Evaluation of Response-Time
Data Involving Transient States: An Illustration Using Heart-Transplant
Data. Journal of the American Statistical Association Journal of the
American Statistical Association 69, no. 345: 81-86.

Simon, Richard, and Robert W Makuch. 1984. A non‐parametric graphical
representation of the relationship between survival and the occurrence
of an event: Application to responder versus non‐responder bias.
Statistics in Medicine 3, no. 1: 35-44.

Steve


> On Oct 9, 2013, at 6:51 AM, Florian Posch wrote:
> 
> Dear Statalisters,
> 
> your help would be very much appreciated on the following:
> 
> I'm working on a dataset where I am modeling the impact of a time-dependent variable (the onset of thrombosis during follow-up) on survival. This analysis works fine with stsplit, and is pretty much the same as done in the Stanford Heart Transplant data example:
> 
> The Stata Journal (2004) 4 , Number 2, pp. 221–222
> Stata tip 8: Splitting time-span records with categorical time-varying covariates
> 
> Again, my analysis works well for the Cox model, Kaplan-Meier survival curves, and the logrank-test (as illustrated in the Staa journal paper above). However, some recent reviews postulate that time-dependent covariates can validly be used in the Cox model but that is is INAPPROPRIATE to use them in Kaplan-Meier survival curves and the logrank test. These reviews suggest that the appropriate substitute methods in this setting are the Simon & Makuch plot (substitute for Kaplan-Meier curves), and the Mantel-Byar test (substitute for the logrank test).
> 
> Searching the web I found some posts in forums and a couple of papers on Pubmed which say that Stata has implemented these methods, however, I could not find such a package on the SSC or anywhere else in Stata. A prior post regarding this issue on statalist remained unanswered:
> 
> http://www.stata.com/statalist/archive/2010-05/msg00079.html
> 
> Do you know where I can find these analysis methods for Stata?
> 
> Thank you very much in advance for your input!
> 
> Flo
> 
> Florian Posch, MSc
> MD PhD Student
> Medical University of Vienna
> *

*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/faqs/resources/statalist-faq/
*   http://www.ats.ucla.edu/stat/stata/