Re: st: Interpretation of Cut Points in Ordered Probit (Logit) Model

[Joerg Luedicke <joerg.luedicke@gmail.com>]

The thresholds, or cut points, reflect the predicted cumulative
probabilities at covariate values of zero. Consider the following
simple example for an ordered logit model with one binary predictor
variable. Have a look at the predicted probabilities from -margins-
(and calculate the cumulative probability for y==2) and compare them
with the predicted cumulative probabilities that are calculated using
the thresholds:

*-------------------

* toy data
clear
sysuse auto

* create outcome with 3 categories
gen y = rep78 - 2 if rep78 > 2

* fit ordered logit model
ologit y i.foreign

* predict probabilities
margins i.foreign, predict(outcome(1))
margins i.foreign, predict(outcome(2))

* cumulative probability for y == 2
di .7098536 + .2397166

* calculate predicted cumulative probabilities for foreign == 0 from cutpoints
di exp(_b[cut1:_cons]) / (1 + exp(_b[cut1:_cons]))
di exp(_b[cut2:_cons]) / (1 + exp(_b[cut2:_cons]))

*-------------------

In principle, this is similar to an ordered probit model, you just
would plug the thresholds into the cumulative standard normal
distribution instead of using the inverse logit transform.

Joerg

On Fri, Apr 26, 2013 at 10:11 AM, Auh, Jun Kyung
<jauh14@gsb.columbia.edu> wrote:
> Thanks. So I need to add back mean of X to generate predicted Y (not Pr(Y=i)) based on the cut points, right?
> Just want to make sure that I understood.
>
> Best,
> JK
>
> -----Original Message-----
> From: owner-statalist@hsphsun2.harvard.edu [mailto:owner-statalist@hsphsun2.harvard.edu] On Behalf Of JVerkuilen (Gmail)
> Sent: Thursday, April 25, 2013 11:40 PM
> To: statalist@hsphsun2.harvard.edu
> Subject: Re: st: Interpretation of Cut Points in Ordered Probit (Logit) Model
>
> On Thu, Apr 25, 2013 at 9:25 PM, Auh, Jun Kyung <jauh14@gsb.columbia.edu> wrote:
>>
>> The regression results show that I have negative value for cut2.
>> If cut2 < 0, wouldn't the model predict that there is zero observation with Y = 1?
>> Or, is the cut points are de-meaned? i.e, do I have to add back the mean of X to have correct interpretation?
>
> Like intercept type parameters in other models, the cuts are relative to the mean of X.
>
>
> --
> JVVerkuilen, PhD
> jvverkuilen@gmail.com
>
> "He uses statistics as a drunken man uses lamp-posts - for support rather than illumination."--Andrew Lang
>
> *
> *   For searches and help try:
> *   http://www.stata.com/help.cgi?search
> *   http://www.stata.com/support/faqs/resources/statalist-faq/
> *   http://www.ats.ucla.edu/stat/stata/
>
> *
> *   For searches and help try:
> *   http://www.stata.com/help.cgi?search
> *   http://www.stata.com/support/faqs/resources/statalist-faq/
> *   http://www.ats.ucla.edu/stat/stata/
*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/faqs/resources/statalist-faq/
*   http://www.ats.ucla.edu/stat/stata/