Re: st: Re: "Meta-analysis" of Proportions

[Steve Samuels <sjsamuels@gmail.com>]

You are welcome, Kathryn.

I meant the Statalist FAQ.

Steve

On Apr 21, 2013, at 10:10 AM, kathryn dennick wrote:

Thank you, both. I don't use Stata, I know very little about it and was lead to believe by a course tutor that my query was not possible and hence would not be covered by FAQs and the like. Instead, I was advised to post here. I also used columns in an attempt to be explicit about the way in which I was entering data. Yes, variables are more appropriate. Thank you.

I also didn't realise my message would go straight to the list, rather I thought the text relating to my query might be extracted as I submitted it to an email address which I presumed might be for for moderation or the like. My apologies, had I realised it would have been tidier and clearly marked etc.

Many thanks for your help. I very much appreciate it.

Best wishes,
Kathryn

Sent from my iPhone

On 21 Apr 2013, at 06:38, "Steve Samuels" <sjsamuels@gmail.com> wrote:

> Welcome to Statalist, Kathryn. 
> 
> You'd do much better if you:
> 1. Read the FAQ
> 2. Put a subject into your emails
> 3. Spelled Stata correctly -not "STATA" (see the FAQ)
> 4. Use Stata, not spreadsheet, terms: you have "variables" that you are inputting, not "columns"
> 
> Unlike a meta-analysis of a causal effect, there is no reason to
> believe that proportions from the different studies will be identical, or
> even similar.  So it is a bad idea to pool studies (add numerators &
> denominators) to get an overall rate. The studies almost certainly have
> different sample sizes and represent different populations. In the
> example below, the largest study has the lowest rate and dominates the
> pooled estimate.  Although you don't mention it, you also need confidence
> intervals.
> 
> Here is model code:
> *********CODE BEGINS************
> /* Save this as "prop01.do" */
> capture log close
> set more off
> log using prop01, replace
> clear
> input study events ntot
> 1 60 300
> 2 60 150
> 3 35 100
> 4 20 60
> end
> 
> gen prop = events/ntot
> 
> /* Convert to a full data set */
> gen no_events = ntot - events
> save d1, replace
> preserve
> 
> keep study events
> gen event = 1
> rename events count
> tempfile t1
> save `t1'
> 
> restore
> keep study no_events
> gen event = 0
> rename no_events count
> append using `t1'
> sort study event
> list
> 
> expand count  //expand to individual records
> save d2, replace
> /* Get separate CIs */
> bys study: ci event, binomial agresti
> 
> /* Overall Proportion */
> 
> /* 1. Pool studies: bad idea
> Weights studies by sample size
> Incorrect idependence assumption for CI
> */
> mean event
> ci event, binomial agresti //same
> 
> /* 2. Arithmetic mean of study proportions: 
> probably best idea*/
> use d1, clear
> ci prop
> 
> 
> /*3. Random Effects Model: assumes normality of study
> effects, which must be checked by plots. Don't use
> it unless you understand it and do the checks. Here, it
> is to the arithmetic mean of the 4 proportions
> and I would use just that and its CI
> */
> use d2, clear
> 
> xtmelogit event  || study:
> nlcom invlogit(_b[_cons])
> *****************CODE ENDS********************
> 
> On Apr 19, 2013, at 12:14 PM, kathryn dennick wrote:
> 
> Hi,
> 
> I am a registered user of STATA and I have a query that I would really like to post in statalist if that's possible at all, please? 
> 
> I am currently undertaking a systematic review of cross sectional studies investigating the prevalence of distress in diabetes. The data I have to synthesise is a simple proportion/percentage (those with distress as a proportion of the total diabetes sample). I have to to synthesise this data in a meta-analysis, and I recently attended a course where I learnt about using the metan code from the online STATA journal to conduct meta-analysis of RD, RR and OR data. I'm obviously not able to use this to undertake the meta-analysis as I don't have this type of data. I am know that in entering the data that I have as 2 columns (i.e. as those with depression and then the total sample size), STATA will not read this as a proportion as I need it to. My query is whether you are aware of any STATA command that exists which would enable me to synthesise the data I have and derive an overall proportion/percentage across the studies being reviewed. 
> *
> *   For searches and help try:
> *   http://www.stata.com/help.cgi?search
> *   http://www.stata.com/support/faqs/resources/statalist-faq/
> *   http://www.ats.ucla.edu/stat/stata/

*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/faqs/resources/statalist-faq/
*   http://www.ats.ucla.edu/stat/stata/


*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/faqs/resources/statalist-faq/
*   http://www.ats.ucla.edu/stat/stata/