Re: st: RE: how do we jointly test coefficients (fuller specification) from diff

[Jorge Eduardo Pérez Pérez <perez.jorge@ur.edu.co>]

Since you are assuming the error terms have different variances, the
stacking approach does not work here, since, as David points out, the
stacking approach assumes the same variance and no correlation. A
proper approach here is seemingly unrelated estimation (SUR), which is
just a kind of multivariate regression. This will allow for different
variance of the error terms as well as correlation. Here's how that
would work:

clear all
version 12
* This just generates some random data. You do not need to do this.
set obs 68
set seed 135
* x variables
gen x1=rnormal()
gen x2=rnormal()
* time
gen time=_n
* 3 y variables (this could be any number of variables, i.e. 25)
glo nvar=3
* Coefficients. I am setting 0 for x1 and 1 for x2. Constants are set to 1,2,3
forv i=1(1)$nvar {
glo b`i'0=`i'
glo b`i'1=0
glo b`i'2=1
}
* Error terms are multivariate normal. Covariance matrix
matrix C=[1,0.2,1\0.2,2,0.3\1,0.3,3]
* Generate error terms
drawnorm e1 e2 e3, cov(C)
* Generate y variables,
forv i=1(1)$nvar {
gen y`i'=${b`i'0}+${b`i'1}*x1+${b`i'2}*x2+e`i'
}
* Now I have a data set like yours.
* Run SUR. For 3 variables I would write sureg (y1 x1 x2) (y2 x1 x2)
(y3 x1 x2). Following code loops for many variables.
glo cmd ""
forv i=1(1)$nvar {
glo cmd " $cmd (y`i' x1 x2)"
}
sureg $cmd
* Test. For 3 variables this could be test [y1]x1 =[y2]x1 =[y3]x1=0
test [y1]x1=0
forv i=2(1)$nvar {
test [y`i']x1=[y1]x1, accum
}
test
_______________________
Jorge Eduardo Pérez Pérez


On Tue, Mar 19, 2013 at 3:41 PM, Arthur Boman <boman@berkeley.edu> wrote:
> David (Jorge can check first part and think if it jives with the code he
> sent),
> ____
>
> Thank you.  This got me thinking more about the model.  Here is my model:
>
> y1= a*x1 + f*x2 + e1
> y2= b*x1 + g*x2 + e2
> y3= c*x1 + h*x2 + e3
>
> e1, e2, e3 are independent, normal, and mean-zero.  They have different
> variances, but it would be okay to assume the variances do not change with
> time.
>
> Then the null is a=b=c=0.
>
> ( When I say independent I mean both cross-sectionally (e1 at any time is
> independent of e2 at any time) and independent across time as well, no
> serial correlation.
>
> Constant variance across time is okay, i.e. not heteroscedastic. If it is
> easy to allow heteroscedasticity and correct for this, then okay. )
>
> ____
>
> Bonferroni:  Yes I had thought of this but I am not sure whether it is
> accurate.  It seems like it should not be far off, or maybe it is accurate.
> What I wondered is whether the x's can be considered predetermined for
> subsequent models, as they are the same for all.  I also wonder if I did
> the tests separately and allowed for heteroscedasticity, would Bonferroni
> work same way?
>
> ____
>
> The fact that "3" is actually 25 makes all of this more "interesting."
>
> ( -:
>
> ____
>
> Don't worry about the priced factor thing.  Testing if coeff on x1's are
> all zero with the other x's in there.
>
> Yes, there are x2, x3, and x4.
>
> ____
>
> Sounds complicated:
>
>> The suggestion of stacking y1, y2, and y3 into a column vector seems
>> to be headed toward a multiple regression (in which the "design"
>> matrix also stacks x1 and x2 for each of the y's) and then perhaps a
>> likelihood-ratio test.  It may be appropriate (or necessary) to take
>> into account correlation among y1, y2, and y3; that would turn the
>> analysis into a multivariate regression with (y1, y2, y3) as the
>> vector dependent variable.  Even without correlation, y1, y2, and y3
>> may not have the same variance.
>>
>> The fact that "3" is actually 25 makes all of this more "interesting."
>>  And maybe your asset-pricing model involves other factors besides x2.
>>
> *
> *   For searches and help try:
> *   http://www.stata.com/help.cgi?search
> *   http://www.stata.com/support/faqs/resources/statalist-faq/
> *   http://www.ats.ucla.edu/stat/stata/
>
>


*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/faqs/resources/statalist-faq/
*   http://www.ats.ucla.edu/stat/stata/