Re: st: tabulate 'hazard ratios' and 'p values' after Cox analysis

[Maarten Buis <maartenlbuis@gmail.com>]

On Tue, Jul 24, 2012 at 4:46 PM, yaacov lawrence wrote:
> I am entering the results of a cox survival analysis into a matrix for
> further analysis.
> looking to tabulate 'hazard ratios' and 'p values', but these are not
> returned by ereturn.

*----------------- begin example ------------------
sysuse cancer, clear
stset studytime, failure(died)
tab drug, gen(d)
drop d1
stcox d? age

mata
b = st_matrix("e(b)")
V = st_matrix("e(V)")

// hazard ratio
hr = exp(b)

// p-value
se = diagonal(cholesky(diag(V)))'
z = b:/se
p = 2*normal(-abs(z))

hr
p
end
*---------------- end example -------------------

Also see:
M.L. Buis (2007), "Stata tip 54: Where did my p-values go?", The Stata
Journal, 7(4), pp.584-586.
<http://www.stata-journal.com/article.html?article=st0137>

Hope this helps,
Maarten

--------------------------
Maarten L. Buis
Institut fuer Soziologie
Universitaet Tuebingen
Wilhelmstrasse 36
72074 Tuebingen
Germany


http://www.maartenbuis.nl
--------------------------
*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/