Re: st: Trends and Time dummies

[Maarten Buis <maartenlbuis@gmail.com>]

On Sun, Sep 11, 2011 at 4:26 PM, Venkiteshwaran, Vinod  wrote:
> I apologize for not making the specification more clear.
> I am attempting to run a regression precisely in the format you have specified in your response.
>  I do have t-1 dummies to avoid the dummy variable trap.
> Adding a trend actually forces me to drop another dummy since the trend variable is a linear transformation of the remaining dummies in the model.
> Therefore in the model with the trend and year dummies I have t-2 time dummy variables.
> I think I follow the interpretation you have provided.
> What complicates the situation I have is in relation to which years were dropped.
> For example, if I drop the first two years, last two years or one at the beginning of the sample and one at the end of the sample.
>
> The focus of my study is on the coefficients of the time dummies and if there is a trend.

Adding a trend does not change your model, it just divides the same
information differently across coefficients. You can see that in the
example below, both models lead to exactly the same predictions. So,
if you find the dummies + trend model hard to interpret then you can,
without loss of information, leave the trend out.

If you let the dummies represent a coarser subdivision, for example
the trend is annual but the dummies represent decades, than these are
two substantively different models. The model with decade indicator
variables allows jumps at the beginning and end of each decade, while
the model with only the trend just represents a linear trend.

*----------------- begin example -----------------
use http://fmwww.bc.edu/repec/bocode/g/gss.dta, clear
gen year = coh*10

// adding a trend does not change the model when
// you have one indicator variable for each year
reg degree i.year c.coh
predict yhat1
reg degree i.year
predict yhat2
twoway scatter yhat1 yhat2, aspect(1) ||    ///
       function identity = x, range(.5 2.1) ///
       ytitle(trend + dummies)              ///
       xtitle(only dummies)

// it does change the model (and may or may not be
// a meaningful compromise between annual dummies and
// one linear trend ) when you enter one indicator
// variable per decade.
gen decade = floor(coh)
reg degree i.decade coh
predict yhat3
reg degree coh
predict yhat4
sort coh
by coh : gen byte mark = _n == 1
twoway line yhat3 coh if mark ||            ///
       line yhat4 coh if mark ||            ///
       scatter yhat2 coh if mark,           ///
       legend(order( 1 "trend + decade"     ///
                     2 "just trend"         ///
                     3 "annual estimate" ))
*------------------ end example ------------------
(For more on examples I sent to the Statalist see:
http://www.maartenbuis.nl/example_faq )

Hope this helps,
Maarten

--------------------------
Maarten L. Buis
Institut fuer Soziologie
Universitaet Tuebingen
Wilhelmstrasse 36
72074 Tuebingen
Germany


http://www.maartenbuis.nl
--------------------------

*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/