Re: st: Y standardization in ologit regressions with -mi-

[Maarten buis <maartenbuis@yahoo.co.uk>]

--- On Tue, 7/12/10, Daniel Escher wrote:
> I performed multiple imputation on a dataset in Stata 11.1
> using -mi impute-. My basic syntax for analysis is:
> . mi est, post: ologit forgive sex age south i.race 
> 
> I would like to obtain standardized coefficients. In
> particular, I would like to have Y-standardization so I can
> compare coefficients across models as discussed in Long &
> Freese's book (http://www.stata-press.com/books/regmodcdvs.html). 

The dificult part is to compute the standard deviation of the latent
dependent variable. Once you have that, you just devide the coefficient
and standard error with that number. Below is how I would compute that
standard deviation:

*----------------- begin example ------------------------
use http://www.stata-press.com/data/r11/mheart0, clear
mi set mlong
mi register imputed bmi
mi register regular attack smokes age hsgrad female alcohol
mi impute regress bmi attack smokes age hsgrad female alcohol, add(20) rseed(2232)
mi estimate, dots post: ologit alcohol attack smokes age bmi hsgrad female

predict xb 
tempname sd_y
scalar `sd_y' = 0
forvalues i = 1/20 {
	mi xeq `i': summarize xb
	scalar `sd_y' = `sd_y' + r(Var)
}
scalar `sd_y' = sqrt(`sd_y' / 20 + _pi^2/3)
di `sd_y'
*------------------------ end example ------------------------------

Hope this helps,
Maarten

--------------------------
Maarten L. Buis
Institut fuer Soziologie
Universitaet Tuebingen
Wilhelmstrasse 36
72074 Tuebingen
Germany

http://www.maartenbuis.nl
--------------------------


      

*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/