Re: st: Svy poststratification VS Pweighting

[Steve Samuels <sjsamuels@gmail.com>]

Franceso,
 It helps in these situations to reproduce the problem with a standard
data set, and to show _all_ the commands and output. The
poststratification options work in this example, set up to have n's
similar to yours. Does it work for you?  The only potential issue I
see in your code snippests: the "if sample==1"  clause implies that
you  -svyset- the whole data set, not just the sample.

*************************CODE BEGINS**************************
sysuse auto, clear
set seed 09865229
gen small = trunk<13
expand 250

replace mpg = mpg + 5*(uniform() -.5)
tab foreign small, nolabel
egen postgp = group(foreign small)
tab postgp

mean mpg   // population mean
mean mpg, over(postgp)

sample 625, by(postgp) count
tab postgp
mean mpg  // unweighted mean


gen     postw=9000 if postgp==1
replace postw=4000 if postgp==2
replace postw=2000 if postgp==3
replace postw=3500 if postgp==4

svyset _n, poststrata(postgp) postweight(postw)
svy: mean mpg
***************************CODE ENDS***************************


On Mon, Jun 21, 2010 at 12:22 PM, francesco manaresi <manaresi@gmail.com> wrote:
> Thank you very much for your answer, Stas. Maybe I was not clear, sorry:
> I did not use the postweight to' multiply pweight. I just Either used
> postweight only (with svy postweight capabilities) or pweight with
> weights calculated as N_h/n_h (the inverse of the prob of being
> selected if strata where design strata - while in fact they Are not).
> In the FIRST case it yields that absurd small St.error which I agree
> with u makes no sense.
> The issue is why using
> svy , poststrata(stratavar) postweight(number_of_obs_in_strata_in_orig_pop)
> yields that micro-s.err.
>
>
>
> On Monday, June 21, 2010, Stas Kolenikov <skolenik@gmail.com> wrote:
>> On Mon, Jun 21, 2010 at 11:42 AM, francesco manaresi <manaresi@gmail.com> wrote:
>>> I've seen several questions on the issue of poststratification in
>>> Statalist, but would like to ask you some clarifications on the
>>> estimate of standard errors. Thank you for your kindness and
>>> availability.
>>> I have got a sample of firms which have been (supposedly) randomly
>>> drawn from a reference population, and would like to post-stratify
>>> based on two observable characteristics for which all cross-tables are
>>> available.
>>
>> The pweight has to be the inverse probability of selection, if
>> available. Period. If you have additional information on the
>> composition of the population, you should use post-stratification
>> capabilities. Using post-stratification adjustments to multiply the
>> original pweights and running anlaysis as if this composite weight
>> were the pure probability weight is a poor man's strategy, and should
>> be discouraged when more appropriate tools are available.
>>
>> I would never trust a standard error of 5e-17 which is roughly
>> c(epsdouble). I don't know what you've done there, but you obviously
>> eliminated the variance in the sample, and you know this cannot be
>> right (unless you sampled all the units with probability of 1, at
>> which point it is not a random sample anymore).
>>
>> As for matching, you are on your own there. I don't trust ANY standard
>> errors that come out of matching estimators, so they are all equally
>> bad, in my eyes. There is no clear population analogue of the matching
>> procedure for the finite population, so -svy:- mode of inference is
>> hardly applicable.
>>
>> --
>> Stas Kolenikov, also found at http://stas.kolenikov.name
>> Small print: I use this email account for mailing lists only.
>> *
>> *   For searches and help try:
>> *   http://www.stata.com/help.cgi?search
>> *   http://www.stata.com/support/statalist/faq
>> *   http://www.ats.ucla.edu/stat/stata/
>>
>
> --
> -------------------------------
> Francesco Manaresi
> Department of Economics
> University of Bologna
> P.zza Scaravilli 2
> 40126 - Bologna (Italy)
>
> Tel: +39-051-209-8887
> Cell: +39-320-112-7417
> Skype: f.manaresi
> URL: www2.dse.unibo.it/francesco.manaresi
>
> *
> *   For searches and help try:
> *   http://www.stata.com/help.cgi?search
> *   http://www.stata.com/support/statalist/faq
> *   http://www.ats.ucla.edu/stat/stata/
>

-- 
Steven Samuels
sjsamuels@gmail.com
18 Cantine's Island
Saugerties NY 12477
USA
Voice: 845-246-0774
Fax:    206-202-4783

*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/