RE: st: AW: AW: Display Variable Labels

["Nick Cox" <n.j.cox@durham.ac.uk>]

-_crcslbl- is an non-documented command to copy one variable label to another. 

CRC was the first name for the company that now is StataCorp. "slbl" is evidently "same label". (The 8.3 filename.ext limit of DOS bit hard on early command names.)  

Despite the lack of a help, the source code is instructive and sufficient. 

*! version 1.1.0  19dec1998
program define _crcslbl	/* varname varname */
	version 6
	args dst src
	local w : variable label `src'
	if `"`w'"' == "" {
		local w "`src'"
	}
	label variable `dst' `"`w'"'
end

Thus the syntax is 

_crcslbl fromvariable tovariable 

Nick 
n.j.cox@durham.ac.uk 

Martin Weiss

" What if I now want to copy the variable label from of pwvssn to a
variable called zpwvssn?"

Let`s give "weight" the -var label- of "mpg":

sysuse auto, clear
d mpg weight
la var weight "`: var l mpg'"
d mpg weight

You can also do things like -clonevar- which copies everything else as well.

Raphael Fraser

Thank you.

pwvssn is just one of 52 variables.

What if I now want to copy the variable label from of pwvssn to a
variable called zpwvssn?

On Thu, May 27, 2010 at 11:03 AM, Martin Weiss <martin.weiss1@gmx.de> wrote:

> BTW, Raphael, what kind of a -varlist- is "pwvssn" in your example? Does
it
> expand to more than one variable?

Martin Weiss

> See -help extended_fcn-:

> sysuse auto, clear
> foreach var of varlist _all{
>        di in r "`: var la `var''"
> }

Raphael Fraser

> foreach var of varlist pwvssn {
>        ...
>        display _newline(3) _column(4) as text "`var'"
>        ta diag, sum(`var')
>        ...
>        }
>
>
> How can I display the variable label rather than the variable name?

*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/