Re: st: graph interaction in count models

[Maarten buis <maartenbuis@yahoo.co.uk>]

--- On Wed, 31/3/10, D Ma wrote:
> I am trying to graph an interaction between two continuous
> covariates in a count model (xtgee y x1 x2 x1*x2 ...,
> family(nb) link(log) vce(robust) nolog).  Do you have
> any suggestions as to how draw such a graph?  Thanks!

*------------------ begin example --------------------
webuse nlswork, clear
xtset idcode year
gen black = race == 2 if inlist(race, 1, 2)

xtgee wks_work c.tenure##c.grade south black, /// 
      family(nb) link(log)

preserve
replace south = 0
replace black = 0
keep if e(sample)
bys grade: keep if _n == 1
expand 5
drop tenure
bys grade: gen tenure = (_n -1)*5
predict wks_hat
separate wks_hat, by(tenure)
twoway line wks_hat? wks_hat?? grade, sort
restore
*--------------------- end example ------------------
(For more on examples I sent to the Statalist see: 
http://www.maartenbuis.nl/example_faq )

Hope this helps,
Maarten

--------------------------
Maarten L. Buis
Institut fuer Soziologie
Universitaet Tuebingen
Wilhelmstrasse 36
72074 Tuebingen
Germany

http://www.maartenbuis.nl
--------------------------


      

*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/