Re: st: Classification table from mlogit

[Maarten buis <maartenbuis@yahoo.co.uk>]

--- On Mon, 22/3/10, Barth Riley wrote:
> Is there something analogous to lstat, which is used for
> producing a classification table after calling the
> logistic procedure, for mlogit? 

It is possible to something similar for -mlogit- by 
assigning someone to a category for which (s)he has the 
highest predicted probability, rather than assigning a
person to a category for which her/his predicted probability
exceeds 50%.

*---------------------- begin example ------------------------
sysuse auto, clear
recode rep78 1/2=3
mlogit rep78 foreign mpg price
predict pr*
tokenize `e(eqnames)'
gen yhat = cond(pr1 == max(pr1,pr2,pr3), `1', ///
           cond(pr2 == max(pr1,pr2,pr3), `2', `3')) if e(sample)
		
tab rep78 yhat
*------------------------ end example ------------------------

However, I would be very careful when using such a method. 
These tables are notoriously sensitive to the marginal 
distribution of your dependent variable. If one category is 
very common, than you can obtain quite a good looking score 
by assigning everybody to that category. Any additional 
information from explanatory variables will only marginaly 
improve your "fit". Explanatory variables will have a much
biger "impact" on getting the prediction righ when the 
marginal proportions of belonging to a category are 
approximately equal. It is however doubtful if such a 
difference is substantively meaningful, as this difference 
comes only from how much variation a baseline model has 
left unexplained. So, this sensitivity to the marginal 
distribution of your depedent variable is most of the time 
not a desirable characteristic for a fit-statistic.

Hope this helps,
Maarten

--------------------------
Maarten L. Buis
Institut fuer Soziologie
Universitaet Tuebingen
Wilhelmstrasse 36
72074 Tuebingen
Germany

http://www.maartenbuis.nl
--------------------------


      

*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/