st: RE: plotting coefficients after quantile regression- beyond grqreg

["Martin Weiss" <martin.weiss1@gmx.de>]

<>

The difficulty here is that -qreg- does not seem to like -fvvarlist-s, which
in other cases make quadratic vars much easier to specify (It does not allow
-coeflegend-, either...). So you want to check this very, very carefully
whether it does what you want:

*******
sysuse auto, clear
gen mpgsq=mpg^2
egen lengthmean=mean(length)
egen turnmean=mean(turn)

foreach quant of numlist 10 25 50 75 90{
	qreg price mpg mpgsq length turn, q(`quant')
	gen pred`quant'=_b[_cons]+_b[mpg]*mpg+_b[mpgsq]*mpgsq+ /* 
	 */ _b[length]*lengthmean+_b[turn]*turnmean
	la var pred`quant' "Quantile `quant'"
}

sort mpg

tw (line pred10 mpg)  /* 
 */ (line pred25 mpg) (line pred50 mpg)  /* 
 */ (line pred75 mpg) (line pred90 mpg)
*******


HTH
Martin


-----Original Message-----
From: owner-statalist@hsphsun2.harvard.edu
[mailto:owner-statalist@hsphsun2.harvard.edu] On Behalf Of Prabhat
Sent: Sonntag, 7. März 2010 15:04
To: statalist@hsphsun2.harvard.edu
Subject: st: plotting coefficients after quantile regression- beyond grqreg

Dear all,

I need your help regarding plots for quantile regression  results. I am new
to STATA as well as quantile regression both.

I am running a quantile regression with independent variable X and its
square term i.e. X^2. there are a number of other variables. however, my
requirement is to show the parabolic curve i.e. dependent variable vs X for
quantile= 0.1,0.25, 0.5, 0.75, 0.9,  keeping all other explanatory variables
at their average value. So, it will be kind of a 5 parabolic curves on a
single plot.

I know there is a very helpful command GRQREG, but it does not plot the
particular estimated coefficients for a number of quantiles on the same
plot. Kindly correct me, if there is any way here.

Further, the only other option I can think of if to do it manually after
getting the results. But, that seems to be a  difficult and tedious task
because i have to repeat it for a number of cycles.

Any suggestion will be highly appreciated.

Thank you.

Regards.
Prabhat Barnwal
International University of Japan

*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/


*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/