Re: st: update seqlogit

[Maarten buis <maartenbuis@yahoo.co.uk>]

--- On Wed, 10/2/10, Ángel Rodríguez Laso wrote:
> I've read with interest your message describing the
> -seqlogit- package and your dissertation  chapter where
> you apply it to describe inequalities of educational
> opportunities. I was thinking about the application of
> this model to outcomes of contact in a survey. <snip>

> 3) It is difficult for me to give levels to the categories.
> Of course, being interviewed is the desired outcome, but I
> cannot say that it is x times more important that other
> outcomes, as you do in your dissertation. On the other hand,
> these other outcomes would definitely have to have the same
> value.

I have been thinking about this problem, and I think there is
a solution that can make sense in your case. To simplify your
problem assume our dependent variable contact has the 
following three categories: 
1= no contact, 2 = refused, 3 = answered

In that case we can think of a sequential proces of contacting
respondents where the first step is to try to contact 
repsondents which might fail (1) or succeed (2 and 3), once 
contact is made respondets can either participate in the survey
(3) or refuse to participate (2)

we are describing in this model the process through which people
choose to participate in a survey or not, so the outcome we care
about is whether a person participate or not. If in the -levels()-
option we assing the value 0 to categories 1 and 2, and the value 
1 to categorie 3, we are decomposing the effect of the variable 
of interest on the probability of participating in the survey.

Below is an example (using data I created myself) illustrating
how I would start such an analysis:

*----------------------- begin example --------------------
// create some data
set seed 12345
drop _all
set obs 1000
gen x = rnormal()
gen z = rnormal()
gen xXz = x*z
gen contact = cond( runiform() > invlogit(2 + 2*x + z + .5*xXz), 1, ///
              cond( runiform() > invlogit(1 + 1.5*x - z + .25*xXz), 2, 3))

// estimate the model			  
seqlogit contact z, ofinterest(x) over(z) tree(1: 2 3, 2 : 3) ///
    levels(1=0, 2=0, 3=1)

preserve
// predict the effect of x on the pr(contact == 3) and 
// how much of that effect is due to the effect of x
// during the first transition and during the second
// transition.

// fix x at the mean (=0)
replace x = 0
replace _x_X_z = 0
 
 forvalues i = 1/2 {
	gen b`i' = [#`i']_b[x] + [#`i']_b[_x_X_z]* z
}

predict w*, trweight 

gen double eff0 = 0
forvalues i = 1/2 {
	gen eff`i' = eff`=`i'-1' + b`i'*w`i'
}

twoway rarea eff0 eff1 z, sort ||             ///
       rarea eff1 eff2 z, sort                ///
       legend(order(1 "contact vs no contact" ///
                    2 "participate vs refuse" ))

// How does the transition probabilities change over z?
// transition 2 is likely to be irrelevant when z is 
// low because virtually everybody at risk passes that
// transition then, similarly transition 1 is likely 
// to be irrelevant for high values of z because everybody
// passes that transition then.
predict pr*, trpr 					
twoway line pr* z, sort					
restore

// These effect of the transition probabilities is caputered
// in the "weights" shown in this decomposition
seqlogitdecomp,                             ///
    overat(z -2, z 0,  z 2)                 ///
    eqlabel("contact vs no contact"         ///
            "participate vs refuse" )       ///
    xline(0) yline(0)  
					
// for more details see Chapter 6 of M.L. Buis (2010) "Inequality 
// of Educational Outcome and Inequality of Educational Opportunity
// in the Netherlands during the 20th Century"
// http://www.maartenbuis.nl/dissertation/
*--------------------------- end example --------------------------
( For more on how to use examples I sent to statalist see:
 http://www.maartenbuis.nl/stata/exampleFAQ.html )

Hope this helps,
Maarten

--------------------------
Maarten L. Buis
Institut fuer Soziologie
Universitaet Tuebingen
Wilhelmstrasse 36
72074 Tuebingen
Germany

http://www.maartenbuis.nl
--------------------------




      

*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/