Paula Albuquerque <[email protected]>:
-mfx- is not really appropriate (and -margins- will refuse to participate).
You need to fully specify what margin you are thinking about to get a
sensible marginal effect. Try calculating the marginal effect of X using
predictions after your -biprobit- and after the user-written command.
E.g.you might want to calculate the conditional prob of Y=1 given X=1
less the cond prob of Y=1 given X=0, letting X=1 and X=0 in turn for
each observation, and then averaging over observations.
sysuse nlsw88, clear
g x=race==1
g y=married
biprobit (y=x grade south smsa) (x=industry occupation union)
mfx
* margins, dydx(*)
g wasx=x
replace x=1
predict p1a, p11
predict p1b, p10
predict p1c, p01
predict p1d, p00
g p1=p1a/(p1a+p1c)
replace x=0
predict p0a, p11
predict p0b, p10
predict p0c, p01
predict p0d, p00
g p0=p0b/(p0b+p0d)
replace x=wasx
drop wasx
g dp=p1-p0
su dp
On Mon, Feb 1, 2010 at 9:57 AM, Paula Albuquerque <[email protected]> wrote:
> Hello.
> I am investigating the effect of a dichotomous variable X on a dichotomous
> variable Y. There is a potential endogeneity problem.
> I estimated a biprobit (one equation with Y as the dependent variable and
> another equation with X as the dependent variable) and mfx after that.
> Therefore, I obtain the marginal effect of the variable X.
> I also tried the simple probit and obtained the marginal effect using mfx.
> A switching probit was estimated with a stata program using ML (my coauthor
> wrote the program) because I think there is no command for that. (One
> equation for Y if X=1, another for Y if X=0, and another for X). In order to
> obtain the effect of X on Y the program calculates the average treatment
> effect.
>
> My problem is the marginal effect of X is rather similar using a probit or a
> biprobit (0,122 and 0,127). However, the average treatment effect obtained
> with the switching probit is much higher (0,468). Is this reasonable? Does
> it mean something is wrong?
>
> I would really be very grateful if someone could help me on this!
>
> Paula Mateus
*
* For searches and help try:
* http://www.stata.com/help.cgi?search
* http://www.stata.com/support/statalist/faq
* http://www.ats.ucla.edu/stat/stata/
