--- On Wed, 2/12/09, Kirimi Sindi wrote:
> How do I plot a graph polynomial to show there is or no
> local inflection point?
>
> I am running:
>
> regress y x xsquared xcubic
>
> Is there a command after the regression to get STATA plot a
> graph?
Just for fun I also added a 95% confidence interval (lb/ub):
*--------------- begin example ----------------------
sysuse nlsw88, clear
gen ttl_exp2 = ttl_exp^2
gen ttl_exp3 = ttl_exp^3
reg wage ttl_exp*
predict yhat, xb
predict se, stdp
gen lb = yhat - invttail(e(df_r),0.025)*se
gen ub = yhat + invttail(e(df_r),0.025)*se
twoway rarea lb ub ttl_exp, sort astyle(ci) || ///
line yhat ttl_exp, sort
*--------------- end example ------------------------
( For more on how to use examples I sent to statalist see:
http://www.maartenbuis.nl/stata/exampleFAQ.html )
Hope this helps,
Maarten
--------------------------
Maarten L. Buis
Institut fuer Soziologie
Universitaet Tuebingen
Wilhelmstrasse 36
72074 Tuebingen
Germany
http://www.maartenbuis.nl
--------------------------
*
* For searches and help try:
* http://www.stata.com/help.cgi?search
* http://www.stata.com/support/statalist/faq
* http://www.ats.ucla.edu/stat/stata/
