Re: st: estimation output of xtreg: rho, chi squared

[Martin Weiss <martin.weiss@uni-tuebingen.de>]

Try this for the calculation:


********
webuse nlswork, clear

    generate age2 = age^2
    generate ttl_exp2 = ttl_exp^2
    generate tenure2 = tenure^2
    generate byte black = race==2
    xtset idcode
xtreg ln_w grade age* ttl_exp* tenure* black not_smsa south, fe
eret li
di e(rho)
*alternative
di e(sigma_u)^2/(e(sigma_e)^2+e(sigma_u)^2)

xtreg ln_w grade age* ttl_exp* tenure* black not_smsa south, re theta
di e(chi2)
*alternative
test grade age  age2 ttl_exp  ttl_exp2 tenure  tenure2 black not_smsa south
***********

Rho denotes the variance due to the random effects u_i, and Stata says  
that quite clearly in its output. Chi2 is the test statistic for the  
joint test that all coefficients estimated are zero...

HTH
Martin



Quoting tutor um <tutor2005um@googlemail.com>:


> Hi everybody,
> I am puzzled of the exact meaning and interpretation of rho and chi
> squared that are saved in e() after regressing with xtreg and other
> panel regression commands.
>
> How are they to be interpreted? Should a higher rho be better?
> And what does the chi squared tell me?
>
> If you have good resource you can recommend I would be very thankful
> to receive a pointer to that.
> Thank you for bringing some light into this for me.
>
> Enrique.
> *
> *   For searches and help try:
> *   http://www.stata.com/help.cgi?search
> *   http://www.stata.com/support/statalist/faq
> *   http://www.ats.ucla.edu/stat/stata/



*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/