Re: st: standard error of the odds ratio

[May Boggess <mboggess@stata.com>]

On Monday morning Kate asked about the standard error of the odds ratio:
> I need to calculate the standard error of the odds ratio and use the "cc"
> command which reports the 95% confidence interval but does not report the
> standard error itself. I would appreciate it very much if anyone could let
> me know if there is a way or an option to specify that the standard error of
> the odds ratio be reported in the output as well.
The epitab command -cc- reports, by default, an exact confidence 
interval for the odds ratio, so there is in fact no standard error when 
the interval is computed this way.

One thing Kate might want to do is to use the Woolf confidence interval. 
One can obtain the upper and lower bounds of the interval using the 
option -woolf- on -tabodds-. A standard error is reported if we use the 
command -logistic- to obtain the Woolf confidence interval. Here is an 
example that shows what I mean by all of this:

 clear
 webuse downs
 expand pop
 cc case exposed
 cc case exposed, wo
 logistic case exposed

Now, you may notice that the interval is not symmetric so one doesn't 
just add and subtract 1.96*se to get the confidence interval. It is in
confidence interval of the log of the odds ratio that is symmteric.
Here is how the above interval is calculated (I'm using the option 
-coef- on -logistic- to show the actual coefficients of the model
as opposed to the odds ratio here):

 logistic case exposed, coef
 display "or = " exp(_b[exposed])		
 display "lb = " exp(_b[exposed]-invnorm(0.975)*_se[exposed])
 display "ub = " exp(_b[exposed]+invnorm(0.975)*_se[exposed])

So what is the standard error that -logistic- reports then?  The 
standard error of the odds ratio is

  display "se(OR) = " exp(_b[exposed])*_se[exposed]

(see [R] logistic, page 67 in version 9 manuals).

--May
mmb@stata.com


*
*   For searches and help try:
*   http://www.stata.com/support/faqs/res/findit.html
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/