st: Re: interpolating quarterly->monthly

[Kit Baum <baum@bc.edu>]

The denton method (like the Chow-Lin approach) distributes the 
observations of a low-frequency series (eg quarterly) to a higher 
frequency (eg monthly) obeying the accounting constraint that if you 
aggregate the resulting series, you reproduce the original. The 
distribution is performed with an 'associated series' or indicator 
variable at the higher frequency; the approach imposes the pattern of 
the indicator variable on the low-frequency series movements within the 
period. Here is an example of how to do that with your series. I don't 
know what a sensible indicator variable would be, so I just used US 
index of industrial production as an illustration. Note the "+2" in the 
gen mm statement; both denton routines require the low-frequency series 
to be aligned with the LAST observation of the period (eg third month 
of quarter, not first or second).

clear
input str8 dt fpi
d�c-87	 	84.2	
mars-88	 	85.6	
juin-88	 	88.4	
sept-88	 	90.9	
d�c-88	 	92.3	
mars-89	 	93.7	
juin-89	 	96.6	
sept-89	 	99.0	
d�c-89	 	99.3	
mars-90	 	99.5	
juin-90	 	102.2	
sept-90	 	101.5	
d�c-90	 	102.5	
mars-91	 	104.7	
juin-91	 	104.3	
sept-91	 	105.0	
d�c-91	 	105.5
end
tsmktim qq, start(1987q4)
g mm = mofd(dofq(qq))+2
format mm %tm
tsset mm
tsfill
save denton1,replace
use http://fmwww.bc.edu/ec-p/data/wooldridge/VOLAT,clear
tsmktim mm, start(1947m1)
drop if tin(,1987m11) | tin(1992m1,)
keep ip mm
save denton2,replace
use denton1
merge mm using denton2
drop _merge
dentonmq fpi, ind(ip) gen(monthly_fpi)
l

Kit Baum, Boston College Economics
http://ideas.repec.org/e/pba1.html

On Nov 13, 2004, at 2:33 AM, statalist-digest wrote:


> I want to generate a monthly series. Kit Baum has proposed the denton 
> method. for the basically generating monthly series from a quarterly 
> one, I know that the stata code is:
>  dentonmq qflow, ind(mflow) gen(minterp)
> But I can't understand what's the indicator variable (mflow) in my 
> case? and How can I have a monthly series with this stata code That I 
> can't understand it? I hope someone will be able to help me with this.

*
*   For searches and help try:
*   http://www.stata.com/support/faqs/res/findit.html
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/